🍬Боодолтой Токэн (Wrapped Token)

Боодолтой токэн гэж юу вэ?

Ямар нэгэн крипто хөрөнгөтэй нэг нэг харьцаатайгаар уягдсан токэнийг боодолтой токэн гэнэ. Tether койн бол USD-той 1:1 харьцаагаар уягдсан койн бөгөөд боодолтой токэн гэж хэлж болох юм. Учир нь 1 tether бүрийн цаана 1$ хадгалагдаж байдаг гэж үздэг. Боодолтой токэнууд нь дараах төрлийнх байж болно.

1. Бодит мөнгөн дэсвгэрт, хувьцаа, хөрөнгөтэй уягдсан

2. Өөрийн блокчэйн дээрх койнтой уягдсан

3. Бусад блокчэйн дээрх койнтой уягдсан

Боодолтой токэн ямар нэг хөрөнгөтэй 1:1 харьцаатай уягддаг тул боодолтой токэн олборлогдох үед уягдсан хөрөнгө ямар агуулахад цоожлогдож, боодолтой токэн шатаагдах үед уягдсан хөрөнгө агуулахаас гардаг.

Яагаад Боодолтой Токэн гэж?

Боодолтой токэн нь бусад блокчэйнд суурилсан койн болон токэнийг эсвэл бодит хөрөнгийг өөрийн блокчэйнд ERC-20 токэн байдлаар ашиглах боломжийг олгодог. Жишээлбэл USD, BitCoin, ETH гэх мэт валют болон криптокойныг боодолтой токэн болгон Корэкс блокчэйнд оруулж ирэх боломжтой. Ямар нэгэн крипто хөрөнгийг блокчэйнд ERC-20 боодолтой токэн болгон оруулж ирэх нь дараах давуу талуудтай.

1. ERC-20-ийн бүх давуу талуудыг хүртэх

2. Гүйлгээний шимтгэл бага блокчэйнд үнийн алдагдалгүйгээр хөрөнгийг захиран зарцуулах.

3. DeFi системүүдээр хөрөнгийг ашиглах

4. Олон токэнуудыг хооронд нь хөрвүүлж, солилцох боломж. DEX-д ашиглах.

Боодолтой токэн хэрхэн үүсгэх вэ?

Энд бид боодолтой токэнийг хэрхэн үүсгэх боломжыг харуулах болно. Боодолтой токэнийг 3 янзаар үүсгэх боломжтой.

1. Итгэмжит гуравдагч этгээд буюу ямар нэгэн биржээр дамжуулан шийдэх

2. Ухаалаг гэрээгээр шийдэх

3. Гүүрийг ашиглах (Гүүр үүсгэх хэсгийг харна уу)

Энд бид эхний хоёр аргыг авч үзэх болно. 3 дахь аргын хувьд гүүр үүсгэх хэсгийг харна уу.

Итгэмжит гуравдагч этгээд буюу ямар нэгэн биржээр дамжуулан шийдэх

Боодолтой токэний ухаалаг гэрээг үүсгэгч нь ихэнхдээ бирж өөрөө, эсвэл бирж өөрөө тухайн боодолтой токэнийг их хэмжээгээр эзэмшсэн этгээд байна. Уг арга нь заавал гуравдагч этгээдээр дамжин хийгдэнэ. Доорх зурагт токэн нь өөр болокчэйн дээр байрлах токэн, койн эсвэл бодит хөрөнгө байна.

Итгэмжит гуравдагч этгээдийг ашиглан боодолтой токэнийг хэрэгжүүлэх

Зурагт үзүүлснээр хэрэглэгч өөрийн эзэмшиж буй токэнийг Худалдаачинруу шилжүүлж, худалдаачин тухайн токэнд харгалзах Боодолтой токэнийг олборлох эсвэл шилжүүлэх замаар хэрэглэгчид яг ижил хэмжээний боодолтой токэн өгнө. Хэрэглэгч боодолтой токэнийг эзэмшиж байгаа хугацаанд Худалдаачин жинхэнэ токэнийг аюулгүй хадгална. Хэрэглэгчийн хүлээн авсан боодолтой токэн нь уг блокчэйн дээр яг л өмнөх токэнтэй адил үнэтэй байх бөгөөд өөрийн мэдлээр зарцуулах боломжтой.

Боолттой токэнийг задлах буюу эргүүлэн хуучин токэн болгохын тулд хэрэглэгч боолттой токэний ухаалаг гэрээнд токэнийг шатаах, эсэл худалдаачинруу шилжүүлэх хүсэлтийг хийнэ. Уг хүсэлт хийгдснээр ухаалаг гэрээг эзэмшигч эсвэл худалдаачин аюулгүй хадгалагдсан хуучин токэнийг хэрэглэгчид шаатаасан эсвэл шилжүүлсэн хэмжээгээр нь эргүүлэн олгоно. Уг зүйлдлийг доорх зурагт үзүүлэв.

Боолтыг задлах буюу эргээд токэноо буцаан авах

Ухаалаг гэрээгээр шийдэх

Нэг блокчэйн дээр орших токэнуудыг боохдоо ухаалаг гэрээнд суурилан хийх боломжтой. Жишээ нь TEO блокчэйн дээрх CRX-ыг дараах ухаалаг гэрээг ашиглан боох боломжтой.

pragma solidity ^0.7.0;

contract WCRX {
    string public name     = "Wrapped CRX";
    string public symbol   = "WCRX";
    uint8  public decimals = 18;

    event  Approval(address indexed src, address indexed guy, uint wad);
    event  Transfer(address indexed src, address indexed dst, uint wad);
    event  Deposit(address indexed dst, uint wad);
    event  Withdrawal(address indexed src, uint wad);

    mapping (address => uint)                       public  balanceOf;
    mapping (address => mapping (address => uint))  public  allowance;

    fallback() external payable {
        deposit();
    }
    function deposit() public payable {
        balanceOf[msg.sender] += msg.value;
        emit Deposit(msg.sender, msg.value);
    }
    function withdraw(uint wad) public {
        require(balanceOf[msg.sender] >= wad);
        balanceOf[msg.sender] -= wad;
        msg.sender.transfer(wad);
        emit Withdrawal(msg.sender, wad);
    }

    function totalSupply() public view returns (uint) {
        return address(this).balance;
    }

    function approve(address guy, uint wad) public returns (bool) {
        allowance[msg.sender][guy] = wad;
        emit Approval(msg.sender, guy, wad);
        return true;
    }

    function transfer(address dst, uint wad) public returns (bool) {
        return transferFrom(msg.sender, dst, wad);
    }

    function transferFrom(address src, address dst, uint wad)
        public
        returns (bool)
    {
        require(balanceOf[src] >= wad);

        if (src != msg.sender && allowance[src][msg.sender] != uint(-1)) {
            require(allowance[src][msg.sender] >= wad);
            allowance[src][msg.sender] -= wad;
        }

        balanceOf[src] -= wad;
        balanceOf[dst] += wad;

        emit Transfer(src, dst, wad);

        return true;
    }
}

Уг гэрээ нь өөр дээрээ CRX хүлээн авах боломжтой бөгөөд CRX шилжүүлсний хариуд тухайн хаягт WCRX токэнийг шилжүүлэн өгөх болно.

Гүүр ашиглан боодолтой токэн үүсгэх

Өөр бусад блокчэйнд суурилсан токэн болон койнуудыг 1-р арга, эсвэл 3-р аргаар боодолтой токэнийг өөрийн блокчэйн дээр үүсгэх боломжтой боломжтой. Гүүр хэсгийг харна уу!